class 基础

class Point
  int x = 3            // 字段：类型 + 默认值
  int y = 4
  func sum() as int   // 方法：self 指当前实例
    return self.x + self.y
  end
end

Point p = Point()      // 调用类型名即构造实例
println(p.x, " ", p.y, " ", p.sum())  // 3 4 7
p.x = 10                // 字段公开可写
println(p.sum())      // 14
auto q = Point()      // auto 推断为 Point
println(type(q))      // Point：type() 回答类名

class Point
  int x
  int y
  create(int x, int y)      // 参数化构造
    self.x = x
    self.y = y              // 不赋值的字段保持零值，不报错
  end
end
Point p = Point(1, 2)
println(p.x + p.y)   // 3

class Tracker
  int id
  create(int id)
    self.id = id
    println(f"create {id}")
  end
  destroy()
    println(f"destroy {self.id}")
  end
end
func scope()
  auto t = Tracker(1)
  println("in scope")
end
scope()                // create 1 → in scope → destroy 1（函数返回即析构）
println("after scope")  // after scope
auto g = Tracker(2)   // create 2；程序结束才 destroy 2

class Counter
  int n = 0
  func inc()
    self.n = self.n + 1
  end
end
Counter a = Counter()
Counter b = a        // 共享，不是复制
b.inc()
println(a.n)          // 1：b 的修改 a 看得见
func bump(Counter c)
  c.inc()
end
bump(a)
println(a.n)          // 2：传参同样共享
println(a == b)       // true：== 比的是引用同一性
println(a == Counter())  // [checked]：构造表达式不能这样用，先赋值再比

class Counter
  static int total = 0          // 类型级字段，全实例共享
  int n = 0
  create()
    Counter.total = Counter.total + 1   // 统计实例数
  end
  static func reset()          // 静态方法：没有 self
    Counter.total = 0
  end
end
Counter a = Counter()
Counter b = Counter()
println(Counter.total)   // 2
Counter.reset()
println(Counter.total)   // 0
Counter.total = 5          // 可写（无 static const 拦截，见拾遗 3）
println(Counter.total)   // 5

class Point
  int x = 1
end
Point p = Point()
auto q = Point()     // auto 推断为 Point（静态类型）
var v = p           // var 装箱，仍是共享引用
v.x = 99              // var 也能点字段（动态分派）
println(p.x)         // 99
println(type(v))     // Point：type() 穿透装箱答类名
println(v is Point)  // true
println(p is int)    // false
Point r             // 裸声明：不构造！
println(r)           // null——访问 r.x 会 fatal 退出

class Account
  private int balance = 0       // 余额外部摸不到
  string owner
  create(string owner)
    self.owner = owner
  end
  func deposit(int amount)
    self.balance = self.balance + amount
  end
  func withdraw(int amount) as bool
    if amount > self.balance then
      return false           // 透支拒绝
    end
    self.balance = self.balance - amount
    return true
  end
  func check() as int
    return self.balance
  end
end
Account acc = Account("小明")
acc.deposit(100)
println(acc.withdraw(30))   // true
println(acc.withdraw(80))   // false：余额不足
println(acc.check())       // 70
Account alias = acc        // 别名共享同一账户
alias.deposit(50)
println(acc.check())       // 120